#!/usr/bin/perl

# MY.M SERVICE CUPID
# $Id: index.cgi,v 1.13 2008/01/21 05:41:37 sedmonds Exp $

use strict;
use warnings;

use Monash::CourseFinder;

use Monash::CourseFinder::CGI qw{
	initialise
	cleanup
	page_header
	page_footer
	get_config
	get_param
	display_course_table
};

use Monash::CourseFinder::Category;

use HTML::Entities qw{
	encode_entities
};

initialise();

my $action = get_param('action') || q{};

if ( $action eq 'search' )
{
	my $query = get_param('query') || q{};

	if ( $query =~ m{ \A \s* \Z }smx )
	{
		display_form(
			'message' => q{Error: please enter at least one search term.},
		);
	}

	my @courses = Monash::CourseFinder->search(
		'query' => $query,
	);

	if ( @courses )
	{
		display_results(
			'courses' => \@courses,
			'query'   => $query,
		);
	}
	else
	{
		display_form(
			'message' => q{No courses were found.  Please change your selections and try again.},
		);
	}
}
else
{
	display_form();
}

###################################

sub display_form
{
	my %arg = @_;

	page_header(
		'heading'   => 'Monash Course Finder',
		'highlight' => 1,
	);

	print
		qq{<h2 class="black"><label for="query">Search</label></h2>\n},
	;

	if ( $arg{'message'} )
	{
		print
			qq{<p>}, encode_entities( $arg{'message'} ), qq{</p>\n},
		;
	}

	print
		qq{<form method="get" action="},
			get_config( qw{ urls index } ),
			qq{">\n},

		qq{<p>For example: accounting, economics, law, medicine</p>\n},

		qq{<p>\n},
		qq{\t<input type="hidden" name="action" value="search" />\n},
		qq{\t<input type="text" size="40" name="query" id="query" value="},
			( get_param('query') || q{} ),
			qq{" />\n},
		qq{\t<input type="submit" value="Go" />\n},
		qq{</p>\n},

		qq{</form>\n},

		qq{<p><a href="},
			get_config( qw{ urls search } ),
			qq{">Advanced search</a></p>\n},

		qq{<h2 class="black">Browse</h2>\n},
		qq{<ul>\n},
	;

	foreach my $category ( Monash::CourseFinder::Category->retrieve_all() )
	{
		print
			qq{\t<li><a href="},
				sprintf( get_config( qw{ urls browse } ), $category->get_url_name() ),
				qq{">},
				encode_entities( $category->get_name() ),
				qq{</a></li>\n},
		;
	}

	print
		qq{</ul>\n};
	;

	page_footer(
		'highlight' => 1,
	);

	cleanup();

	exit;
}


sub display_results
{
	my %arg = @_;

	page_header(
		'heading' => 'Search results',
		'breadcrumbs' => [
			{
				'title' => 'Search results',
			},
		],
	);

	print
		qq{<p><strong>You searched for: </strong> },
			encode_entities( $arg{'query'} ),
			qq{</p>\n},
	;

	display_course_table(
		'courses' => $arg{'courses'},
		'query'   => $arg{'query'},
	);

	page_footer();

	cleanup;

	exit;
};